Rules for integrands of the form (((a+b ArcSin[c x]))^n)

1:  ∫(((a+b ArcSin[c x]))^n)dx  when  n>0

Derivation: Integration by parts

Basis: (∂_x)(((a+b ArcSin[c x]))^n)==((b c n (((a+b ArcSin[c x]))^(n-1)))/(Sqrt[1-(c^2) (x^2)]))

Rule: If  n>0, then

∫(((a+b ArcSin[c x]))^n)dx  ⟶  x (((a+b ArcSin[c x]))^n)-b c n∫((x (((a+b ArcSin[c x]))^(n-1)))/(Sqrt[1-(c^2) (x^2)]))dx

Program code:

Int[(a_.+b_.*ArcSin[c_.*x_])^n_.,x_Symbol] :=
  x*(a+b*ArcSin[c*x])^n - 
  b*c*n*Int[x*(a+b*ArcSin[c*x])^(n-1)/Sqrt[1-c^2*x^2],x] /;
FreeQ[{a,b,c},x] && GtQ[n,0]

Int[(a_.+b_.*ArcCos[c_.*x_])^n_.,x_Symbol] :=
  x*(a+b*ArcCos[c*x])^n + 
  b*c*n*Int[x*(a+b*ArcCos[c*x])^(n-1)/Sqrt[1-c^2*x^2],x] /;
FreeQ[{a,b,c},x] && GtQ[n,0]

2:  ∫(((a+b ArcSin[c x]))^n)dx  when  n<-1

Derivation: Integration by parts

Basis: ((((a+b ArcSin[c x]))^n)/(Sqrt[1-(c^2) (x^2)]))==(∂_x)((((a+b ArcSin[c x]))^(n+1))/(b c (n+1)))

Basis: (∂_x)(Sqrt[1-(c^2) (x^2)])==-(((c^2) x)/(Sqrt[1-(c^2) (x^2)]))

Rule: If  n<-1, then

∫(((a+b ArcSin[c x]))^n)dx  ⟶  (((Sqrt[1-(c^2) (x^2)]) (((a+b ArcSin[c x]))^(n+1)))/(b c(n+1)))+(c/(b (n+1)))∫((x (((a+b ArcSin[c x]))^(n+1)))/(Sqrt[1-(c^2) (x^2)]))dx

Program code:

Int[(a_.+b_.*ArcSin[c_.*x_])^n_,x_Symbol] :=
  Sqrt[1-c^2*x^2]*(a+b*ArcSin[c*x])^(n+1)/(b*c*(n+1)) + 
  c/(b*(n+1))*Int[x*(a+b*ArcSin[c*x])^(n+1)/Sqrt[1-c^2*x^2],x] /;
FreeQ[{a,b,c},x] && LtQ[n,-1]

Int[(a_.+b_.*ArcCos[c_.*x_])^n_,x_Symbol] :=
  -Sqrt[1-c^2*x^2]*(a+b*ArcCos[c*x])^(n+1)/(b*c*(n+1)) - 
  c/(b*(n+1))*Int[x*(a+b*ArcCos[c*x])^(n+1)/Sqrt[1-c^2*x^2],x] /;
FreeQ[{a,b,c},x] && LtQ[n,-1]

3:  ∫(((a+b ArcSin[c x]))^n)dx

Derivation: Integration by substitution

Basis: F[a+b ArcSin[c x]]==(1/(b c)) Subst[F[x] Cos[-(a/b)+(x/b)],x,a+b ArcSin[c x]] (∂_x)(a+b ArcSin[c x])

Rule:

∫(((a+b ArcSin[c x]))^n)dx  ⟶  (1/(b c)) Subst[∫(x^n) Cos[-(a/b)+(x/b)]dx,x,a+b ArcSin[c x]]

Program code:

Int[(a_.+b_.*ArcSin[c_.*x_])^n_,x_Symbol] :=
  1/(b*c)*Subst[Int[x^n*Cos[-a/b+x/b],x],x,a+b*ArcSin[c*x]] /;
FreeQ[{a,b,c,n},x]

Int[(a_.+b_.*ArcCos[c_.*x_])^n_,x_Symbol] :=
  -1/(b*c)*Subst[Int[x^n*Sin[-a/b+x/b],x],x,a+b*ArcCos[c*x]] /;
FreeQ[{a,b,c,n},x]